Specifying Semantic Actions in YACC

Specifying Semantic Actions in YACC

1. Specifying actions in YACC is easy. You simply place C code which performs the action in braces (i.e. `{' and `}') at the point in the production where you want the action to occur.
   • You can put actions in the middle of rules. Putting them only at the ends, however, is a bit safer.
2. Passing semantic values around is a bit trickier. The mechanisms used are illustrated in Figure *. The actions in the example grammar cause the parser to take whatever date is read and echo it in the "standard" form "March 7, 2004".
   • Yacc keeps the semantic values associated with a terminal or non-terminal symbol in its parse stack until the phrase containing the symbol is reduced. We will not worry for now about how the scanner passes a "token value" to Yacc (in addition to a token number).
   • In an action, $1,$2, ... can be used to refer to the values associated with the symbols in the right hand side of the production.
   • In an action, $$ can be used to refer to the value associated with the non-terminal on the left hand side of the production. Typically, $$ appears as the target of an assignment in an action.
   • Declarations of types and variables used in the actions can be placed in the first section of the YACC input file if preceded by a line containing the characters "%{" and followed by a line containing "%}".
3. If semantic values of any type other than integer are used, you must define the type name "YYSTYPE" to describe the type used (This definition can be included in the first section of the input file).
4. If the type YYSTYPE is a union type (it usually is) you should (can, must) tell YACC which member of the union will be associated with each terminal and non-terminal whose value is set or used.
   • For tokens this is done by including the member name between `<' and `>' symbols in each %token declaration.
   • For non-terminals a separate %type declaration is used.

   %{
   typedef union{
     int num;
     char *str;
   } YYSTYPE;
   
   char *monthtab[] =
     {   "January",      "February",       "March",        "April",
         "May",          "June",           "July",         "August",
         "September",    "October",        "November",     "December"     };
   %}
   
   %token <str> MONTH
   %token <num> NUMBER
   
   %type <str> monthnum
   %type <num> day year
   %%
   date : day MONTH year            { printf("%s %d, %d", $2, $1, $3); }
        | monthnum '/' day '/' year { printf("%s %d, %d", $1, $3, $5); }
        | MONTH day ',' year        { printf("%s %d, %d", $1, $2, $4); }
        ;
   
   monthnum : NUMBER           { $$ = monthtab[$1 - 1 ] ; }
            ;
   
   day  : NUMBER ;
   
   year : NUMBER ;
   

    

Specifying Semantic Actions in YACC